MacroFacili: Backup del file con nome

Questa macro consente di fare una copia di Backup in automatico del file che stiamo utilizzando all'interno di una cartella e mantenendo le versioni precedenti.

Il file di backup viene salvato:

con lo stesso nome originale a cui sono aggiunti anno,mese,giorno nel formato AAAAMMGG;
nella cartella indicata da CartBck, che è impostata come Backup nello stesso percorso del file;
nel caso sia già presente un nome di backup (già fatto nella stessa data) viene aggiunta la versione -2,-3,-4...

Sub Backup()
  Dim Wb As Workbook
  Set Wb = Application.ThisWorkbook

  'nome del file originale completo di percorso
  CartFile = Wb.Path
  NomeFile = Wb.Name
  'cartella in cui effettuare il backup
  CartBck = CartFile & "\Backup"
  If (Dir(CartBck, vbDirectory) = "") Then
    MkDir Path:=CartBck
  End If

  'nome del file di bakcup
  p = InStrRev(NomeFile, ".", -1, vbTextCompare)
  NomeBck = Left(NomeFile, p - 1) & "-" & Format(Now(), "yyyymmdd") & Mid(NomeFile, p, 10)

  'verifica che non sia già presente un file di backup con lo stesso nome
  If (Dir(CartBck & "\" & NomeBck) <> "") Then
    Nr = 2
    While (Dir(CartBck & "\" & NomeBck) <> "")
      NomeBck = Left(NomeFile, p - 1) & "-" & Format(Now(), "yyyymmdd") & _
               "-" & Nr & Mid(NomeFile, p, 10)
      Nr = Nr + 1
    Wend
  End If

  'salva il file di backup e ritorna all'orginale
  Application.DisplayAlerts = False
  Wb.SaveAs CartBck & "\" & NomeBck
  Wb.SaveAs CartFile & "\" & NomeFile
  Application.DisplayAlerts = True
End Sub