Le tabelle in Excel sono dei riferimenti strutturati a gruppi di celle che possono facilitare il lavoro con dati in forma tabellare, come gli elenchi.
Definire una tabella
 Volendo partire da una tabella da un intervallo di dati come quello nell'esempio è sufficiente selezionare l'intervallo e usare Ctrl+T, apparirà la finestra di creazione come nell'immagine a lato. |
 Il risultato sarà una tabella formattata con il modello base, come questa. |
 Selezionando una cella della tabella appare la parte della barra multifunzione con i comandi specifici, fra cui il nome della tabella, il formato, la visualizzazione dei totali, ecc. |
 Le tabelle definite nel foglio appaiono anche, pur non essendo dei semplici intervalli, nella gestione dei nomi: si possono distinguere dall'icona differente. |
Formule con tabelle
Il modo più semplice per scrivere formule all'interno di tabelle o che si riferiscono a tabelle è selezionare le celle con il mouse, in questo modo Excel convertirà la selezione nel riferimento strutturato.
Ad esempio volendo calcolare il netto nel nostro esempio scriveremo in una cella della colonna E (non è necessario che sia la prima: essendo una tabella varrà per tutta la colonna): =[@Fatturato]*(1-[@[Sconto%]])
Per i dati presenti in una specifica colonna si potrà scrivere come riferimento NomeTabella[NomeColonna], nel nostro esempio sarebbe TabClienti[Sconto%].
E' una forma semplificata che si riferisce alla sola parte dei dati, come nell'esempio precedente nelle formule di riga vengono omessi i riferimenti alla tabella.
Nella forma generale il riferimento sarà scritto come NomeTabella[[Specificatore];[Colonna]], gli specificatori possibili sono questi:
| Specificatore | Si riferisce a: |
|---|
| #Tutti | Intera colonna, compresa di intestazioni e totali |
| #Dati (predefinito) | Solo ai dati |
| #Intestazioni | Celle di intestazioni, se prensente altrimenti genera un #RIF! |
| #Totali | La riga dei totali, se presente altrimenti genera un #RIF! |
| @ | Stessa riga |
|
 Alcuni esempi di formule basate su questa tabella aiuteranno a capire le differenze. |
| Formula | Si riferisce a | Risultato |
|---|
| =CONTA.VALORI(TabClienti) | Intera area dati | 20 |
| =CONTA.VALORI(TabClienti[Cliente]) | Area dati della colonna cliente | 5 |
| =CONTA.VALORI(TabClienti[[#Tutti];[Cliente]]) | Intera colonna cliente | 7 |
| =CONTA.VALORI(TabClienti[#Intestazioni]) | Intestazioni | 4 |
| =TabClienti[[#Totali];[Fatturato]] | Il valore di totale della colonna fatturato | 810 |
| =1-TabClienti[[#Totali];[Netto]]/TabClienti[[#Totali];[Fatturato]] | Sconto medio (cella D8) | 15% |
|
Formule particolari
Le formula all'interno delle tabelle o che si riferiscono a tabelle dovrebbero essere scritte sempre utilizzando i riferimenti strutturati, le formule che usano riferimenti di cella funzionano ma hanno alcuni problemi, ad esempio quando le dimensioni della tabella cambiano, e sono fortemente sconsigliate.
Il problema può essere che i riferimenti strutturati predefiniti sono riferiti principalmente alla singola riga o parti specifiche della tabella, possiamo però utilizzare alcuni accorgimenti per scrivere formule "compatibili" con quella logica.
Subtotali progressivi
Un esempio pratico è di certo quello di una colonna con totale progressivo, con i riferimenti normali nel nostro esempio scriveremmo in F3 =SOMMA(C$3:C3), che sembra funzionare bene ma quando inseriamo nuove righe le ultime "sballano".
Utilizzando la logica delle formule di tabella dovremmo sommare dalla prima riga cella della colonna che ci interessa alla riga attuale, quindi nel caso della colonna fatturato del nostro esempio sarà:
=SOMMA(INDICE(
[Fatturato];1):[@Fatturato])
Ultima cella dati di una colonna
Volendo ad esempio aggiungere un "totale" al fatturato progressivo dell'esempio precedente dovremo fare come nella formula precedente utilizzando le funzioni che Excel ci mette a disposizione per le matrici. Con i dati del nostro esempio per F8 sarà:
=INDICE(
[Fatt.Progr.];RIGHE([Fatt.Progr.]))
Valore della cella precedente
Volendo indicare il contentuo delle cella immediatamente precedente sulla colonna dobbiamo utilizzare sempre la funzione scarto, ad esempio se avessimo una colonna "indice" in cui abbiamo un criterio di selezione delle righe, in un modo simile a questo:
=SCARTO([@[Selezione]];-1;0)
L'esempio completo é scaricabile da questo link:
Es413.xlsx
Gli esempi contenuti nel sito sono per uso personale, non é consentito l'uso professionale, commerciale o la riproduzione senza autorizzazione.
